• OFN_PATHMUSTEXIST – данный флаг не дает ввести имя файла в несуществующей папке (например, при вводе c: \docs\mydoc1.doc, если папки docs не существует, будет выдано соответствующее сообщение);

• OFN_HIDEREADONLY – позволяет скрыть флажок Только для чтения.

Теперь отдельно рассмотрим, зачем в приведенном примере вызывается дополнительная функция PrepareFilterString (листинг 2.24).

procedure PrepareFilterString(var strFilter: string);

var

i: Integer;

begin

for i:= 1 to length(strFilter) do

if (strFilter[i] = '|') then strFilter[i]:= #0;

end;

Дело в том, что при задании фильтров (поле lpstrFile) требуется, чтобы каждое название и обозначение фильтров были отделены символом #0, а за последним фильтром шла последовательность из двух нулевых символов. На практике задавать строку из нескольких фильтров в следующем виде недостаточно удобно:

'Текстовые файлы'+ #0 + '*.txt'+ #0 + 'Все файлы'+ '*.*'+ #0 + #0

Поэтому часто применяются другие разделители, которые впоследствии преобразуются в символы #0. В данном случае в качестве разделителя используется символ |, благодаря чему приведенная выше строка фильтра может быть записана так:

'Текстовые файлы|*.txt |Все файлы|*.*||'

Согласитесь, что получилось более кратко и понятно.

Теперь обратимся к окну сохранения файла. Для его вызова достаточно переделать код из листинга 2.23 следующим образом (листинг 2.25).

function ShowSave(strFilter: string; nFilterIndex: Integer = 0;

strInitFileName: string = '';

strTitle: string = 'Сохранение файла'):string;

var

ofn: OPENFILENAME;

begin

ZeroMemory(Addr(ofn), SizeOf(ofn));

//Формирование буфера (260 символов)

SetLength(strInitFileName, MAX_PATH);

PrepareFilterString(strFilter);

//Заполнение структуры для окна

ofn.lStructSize:= SizeOf(ofn);

ofn.hWndOwner:= hParentWnd;

ofn.hInstance:= hAppInst;

ofn.lpstrFilter:= PAnsiChar(strFilter);

ofn.nFilterIndex:= nFilterIndex;

ofn.lpstrFile:= PAnsiChar(strInitFileName);

ofn.nMaxFile:= MAX_PATH;

ofn.lpstrTitle:= pAnsiChar(strTitle);

ofn.Flags:= OFN_PATHMUSTEXIST or OFN_OVERWRITEPROMPT;

//Отображение окна и обработка результата

if (GetSaveFileName(ofn) = True) then

ShowSave:= ofn.lpstrFile;

end;

Здесь дополнительно к упомянутому ранее флагу OFN_PATHMUSTEXIST добавлен флаг OFN_OVE RWRITEPROMPT для того, чтобы при указании имени уже существующего файла был задан вопрос, желает ли пользователь заменить этот файл.

Код вызова следующего окна – окна для выбора цвета – приведен в листинге 2.26.

function ShowChooseColor(lastColor: COLORREF = 0):COLORREF;

var

choose: TChooseColor;

begin

ZeroMemory(Addr(choose), SizeOf(choose));

//Заполнение структуры для окна

choose.lStructSize:= SizeOf(choose);

choose.hWndOwner:= hParentWnd;

choose.hInstance:= hAppInst;

choose.rgbResult:= lastColor;

choose.lpCustColors:= Addr(colors);

choose.Flags:= CC_RGBINIT or CC_ANYCOLOR or CC_FULLOPEN;

//Отображение окна и обработка результата

if (ChooseColor(choose) = True) then ShowChooseColor:= choose.rgbResult

else ShowChooseColor:= lastColor;

end;

Здесь также заполняется специальная структура. Для этого используются следующие флаги:

• CC_RGBINIT – использовать значение поля rgbResult в качестве предустановленного значения цвета (по умолчанию как ранее выбранного);

• CC_ANYCOLOR – отображать все доступные предопределенные цвета (левая половина, рис. 2.4);

Рис. 2.4. Окно для выбора цвета

• CC_FULLOPEN – раскрывать панель подбора цвета (правая половина окна, рис. 2.4).